# Capture whether this is a release/debug build.
CONFIG(debug, debug|release) {
    # Target name.
    TARGET = cored
}
CONFIG(release, debug|release) {
    # Target name.
    TARGET = core
}

TEMPLATE = lib

DEFINES += OPMAPCORE_LIBRARY
DEFINES += QtOpmapCore


#VS的补丁 使用 自定义的数学常数

DEFINES += _USE_MATH_DEFINES


#目标生成路径
DESTDIR         = $$PWD/../../bin
MOC_DIR         = $$PWD/../../build
OBJECTS_DIR     = $$PWD/../../build

QT += network
QT += sql
CONFIG += staticlib\
          plugin

SOURCES += opmaps.cpp \
    pureimagecache.cpp \
    pureimage.cpp \
    rawtile.cpp \
    memorycache.cpp \
    cache.cpp \
    languagetype.cpp \
    providerstrings.cpp \
    cacheitemqueue.cpp \
    tilecachequeue.cpp \
    alllayersoftype.cpp \
    urlfactory.cpp \
    placemark.cpp \
    point.cpp \
    size.cpp \
    kibertilecache.cpp \
    diagnostics.cpp
HEADERS += opmaps.h \
    coreglobal.h \
    mathdefine.h \
    size.h \
    maptype.h \
    pureimagecache.h \
    pureimage.h \
    rawtile.h \
    memorycache.h \
    cache.h \
    accessmode.h \
    languagetype.h \
    providerstrings.h \
    cacheitemqueue.h \
    tilecachequeue.h \
    alllayersoftype.h \
    urlfactory.h \
    geodecoderstatus.h \
    placemark.h \
    point.h \
    kibertilecache.h \
    debugheader.h \
    diagnostics.h





#hander
INCLUDEPATH += $$DESTDIR/include




win32|win64 {
    src_dir = $$PWD\\*.h
    dst_dir = $$DESTDIR\\include\\
    # dst_dir 最后的 \\ 是必须的，用来标示 xcopy 到一个文件夹，若不存在，创建之

    # Replace slashes in paths with backslashes for Windows
    src_dir ~= s,/,\\,g
    dst_dir ~= s,/,\\,g

    system(xcopy $$src_dir $$dst_dir /y /e)
}

unix {
    src_dir = $$PWD/*.h
    dst_dir = $$PWD/../../thirdpart/include/

    !exists($$dst_dir): system(mkdir -p $$dst_dir)

    system(cp $$src_dir $$dst_dir -arf )
}