QT += core gui network
#QT += axcontainer

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

# Target name.
CONFIG(debug, debug|release){
    # 在DEBUG 版本后加入 d后缀
    TARGET = $$join(TARGET,,,d)
}


TEMPLATE = lib

DEFINES += MAV_LIBRARY


CONFIG += resources_big


# The following define makes your compiler emit warnings if you use
# any feature of Qt which has been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0



# include sub project

DESTDIR         = $$PWD/../bin
MOC_DIR         = $$PWD/../build
OBJECTS_DIR     = $$PWD/../build

DEFINES         += QtMavlinkNode


HEADERS += \
    Terminal.h \
    ThreadTemplet.h \
    commandprocess.h \
    mavlinknode.h \
    parameterprocess.h \
    missionprocess.h \
    mavlinknodeglobal.h \
    rcprocess.h \
    replay.h \
    rtkprocess.h \
    sbusparser.h \
    statusprocess.h

SOURCES += \
    Terminal.cpp \
    ThreadTemplet.cpp \
    commandprocess.cpp \
    mavlinknode.cpp \
    parameterprocess.cpp \
    missionprocess.cpp \
    rcprocess.cpp \
    replay.cpp \
    rtkprocess.cpp \
    sbusparser.cpp \
    statusprocess.cpp

INCLUDEPATH += $$DESTDIR/include

# Capture whether this is a release/debug build.
CONFIG(debug, debug|release) {
    LIBS += -L$$DESTDIR -lcored
    LIBS += -L$$DESTDIR -linternalsd
    LIBS += -L$$DESTDIR -lopmapwidgetd
}
CONFIG(release, debug|release) {
    LIBS += -L$$DESTDIR -lcore
    LIBS += -L$$DESTDIR -linternals
    LIBS += -L$$DESTDIR -lopmapwidget
}





#添加mavlink目录


INCLUDEPATH += $$PWD/../mavlink \
               $$PWD/../mavlink/ardupilotmega \
               $$PWD/../mavlink/common \
               $$PWD/../mavlink/icarous \
               $$PWD/../mavlink/uAvionix \
               $$PWD/../mavlink/XYK \
               $$PWD/../mavlink/message_definitions



win32|win64 {
    src_dir = $$PWD\\*.h
    dst_dir = $$PWD\\..\\bin\\include\\
    # dst_dir 最后的 \\ 是必须的，用来标示 xcopy 到一个文件夹，若不存在，创建之

    # Replace slashes in paths with backslashes for Windows
    src_dir ~= s,/,\\,g
    dst_dir ~= s,/,\\,g

    system(xcopy $$src_dir $$dst_dir /y /e)

}


unix {
    src_dir = $$PWD/*.h
    dst_dir = $$PWD/../bin/include/

    !exists($$dst_dir): system(mkdir -p $$dst_dir)

    system(cp $$src_dir $$dst_dir -arf )
}