QT += widgets
QT += opengl
QT += network
QT += sql
QT += svg

#execution_character_set("utf-8")

# Capture whether this is a release/debug build.
CONFIG(debug, debug|release) {
    # Target name.
    TARGET = opmapwidgetd
}
CONFIG(release, debug|release) {
    # Target name.
    TARGET = opmapwidget
}

TEMPLATE = lib


DEFINES += OPMAPWIDGET_LIBRARY

DEFINES += QtopmapWidget


#VS的补丁 使用 自定义的数学常数

DEFINES += _USE_MATH_DEFINES
#目标生成路径
DESTDIR         = $$PWD/../../thirdpart/lib
MOC_DIR         = $$PWD/../../build
OBJECTS_DIR     = $$PWD/../../build


CONFIG += resources_big

SOURCES +=  $$PWD/mapgraphicitem.cpp \
            $$PWD/opmapwidget.cpp \
            $$PWD/configuration.cpp \
            $$PWD/waypointitem.cpp \
            $$PWD/uavitem.cpp \
            $$PWD/gpsitem.cpp \
            $$PWD/trailitem.cpp \
            $$PWD/homeitem.cpp \
            $$PWD/mapripform.cpp \
            $$PWD/mapripper.cpp \
            $$PWD/traillineitem.cpp \
            $$PWD/waypointline.cpp \
            $$PWD/waypointcircle.cpp \
            $$PWD/AltitudeItem.cpp

HEADERS +=  $$PWD/mapgraphicitem.h \
            $$PWD/opmapwidget.h \
            $$PWD/configuration.h \
            $$PWD/waypointitem.h \
            $$PWD/uavitem.h \
            $$PWD/gpsitem.h \
            $$PWD/uavmapfollowtype.h \
            $$PWD/uavtrailtype.h \
            $$PWD/trailitem.h \
            $$PWD/homeitem.h \
            $$PWD/mapripform.h \
            $$PWD/mapripper.h \
            $$PWD/traillineitem.h \
            $$PWD/waypointline.h \
            $$PWD/waypointcircle.h \
            $$PWD/mapwidgetglobal.h \
            $$PWD/AltitudeItem.h

RESOURCES += mapresources.qrc

FORMS += \
    mapripform.ui \

INCLUDEPATH += $$PWD/../../thirdpart/include

#添加mavlink目录
INCLUDEPATH += $$PWD/../../mavlink \
               $$PWD/../../mavlink/ardupilotmega \
               $$PWD/../../mavlink/common \
               $$PWD/../../mavlink/icarous \
               $$PWD/../../mavlink/uAvionix \
               $$PWD/../../mavlink/XYK \
               $$PWD/../../mavlink/message_definitions

# Capture whether this is a release/debug build.
CONFIG(debug, debug|release) {
    LIBS += -L$$PWD/../../thirdpart/lib -lcored
    LIBS += -L$$PWD/../../thirdpart/lib -linternalsd
}
CONFIG(release, debug|release) {
    LIBS += -L$$PWD/../../thirdpart/lib -lcore
    LIBS += -L$$PWD/../../thirdpart/lib -linternals
}

win32|win64 {
    src_dir = $$PWD\\*.h
    dst_dir = $$PWD\\..\\..\\thirdpart\\include\\
    # dst_dir 最后的 \\ 是必须的，用来标示 xcopy 到一个文件夹，若不存在，创建之

    # Replace slashes in paths with backslashes for Windows
    src_dir ~= s,/,\\,g
    dst_dir ~= s,/,\\,g

    system(xcopy $$src_dir $$dst_dir /y /e)


    #复制qml文件
    qml_src_dir = $$PWD\\*.qml
    qml_dst_dir = $$PWD\\..\\..\\app_bin\\qml\\
    # dst_dir 最后的 \\ 是必须的，用来标示 xcopy 到一个文件夹，若不存在，创建之

    # Replace slashes in paths with backslashes for Windows
    qml_src_dir ~= s,/,\\,g
    qml_dst_dir ~= s,/,\\,g

    system(xcopy $$qml_src_dir $$qml_dst_dir /y /s)
}


unix {
    src_dir = $$PWD/*.h
    dst_dir = $$PWD/../../thirdpart/include/

    !exists($$dst_dir): system(mkdir -p $$dst_dir)

    system(cp $$src_dir $$dst_dir -arf )
}